有關excel尋找目標問題

由於問題內未有提及B,C,D,E欄的車位車牌記錄有何分別，現假設每一個A欄的車場車位可停泊4部車。此外亦未有提及共有多少個車場車位，現先假設有5個，從CP01至CP05 (CP=Car Park)。現虛擬鍵入車牌為「123」和車位及車牌分佈在A7:E12如下：

車場車位車位車牌1車位車牌2車位車牌3車位車牌4
CP01BB123AA135PQ456CA138
CP02BC123AC123AM999CN168
CP03BD234HK168AT123
CP04ILUGF123GM123
CP05123MM1234123
注意：如車牌只包含數字，輸入數據時須以單引號 ' 開始，將數據轉為文字方便公式處理。

按問題要求配合此處數據是要將所有車牌右端包含鍵入車牌「123」的車牌及車位顯示出來，在虛擬數據中脗合的計有9個：

車場車位車位車牌
CP01BB123
CP02BC123AC123
CP03AT123
CP04GF123GM123
CP05123MM1234123

問題只要求輸出車位至B1:E1四個單元格，但鑑於同時間可以有多個符合的車牌，所以現將輸出添加至四列B1:E4。
亦由於可輸出多個車牌關係，輸出似乎應包含車牌和車位，利便區別和避免產生混淆，故將輸出格式定為「車牌/車位」，例如「BB123/CP01」。
而每欄內符合車牌數目計算到第6列上(A6:E6)，當中A6代表符合車牌總數。
公式設計如下：
A1: 輸入車牌數據(例：123)
B1: =IF(NOT(ISNA(MATCH("*"&$A$1,B$8:B$12,0))),IF(MATCH("*"&$A$1,B$8:B$12,0)>0,INDEX(B$8:B$12,MATCH("*"&$A$1,B$8:B$12,0))&"/"&INDEX($A$8:$A$12,MATCH("*"&$A$1,B$8:B$12,0)),""),"")
C1:E1 Copy from B1
A2: 「輸入車牌」提示標籤
B2: =IF(ROW()<=B$6,INDEX(OFFSET(B$8:B$12,MATCH(LEFT(B1,FIND("/",B1)-1),B$8:B$12,0),,ROWS(B$8:B$12)-MATCH(LEFT(B1,FIND("/",B1)-1),B$8:B$12,0),1),MATCH("*"&$A$1,OFFSET(B$8:B$12,MATCH(LEFT(B1,FIND("/",B1)-1),B$8:B$12,0),,ROWS(B$8:B$12)-MATCH(LEFT(B1,FIND("/",B1)-1),B$8:B$12,0),1),0))&"/"&INDEX(OFFSET($A$8:$A$12,MATCH(LEFT(B1,FIND("/",B1)-1),B$8:B$12,0),,ROWS(B$8:B$12)-MATCH(LEFT(B1,FIND("/",B1)-1),B$8:B$12,0),1),MATCH("*"&$A$1,OFFSET(B$8:B$12,MATCH(LEFT(B1,FIND("/",B1)-1),B$8:B$12,0),,ROWS(B$8:B$12)-MATCH(LEFT(B1,FIND("/",B1)-1),B$8:B$12,0),1),0)),"")
B2:E4: Copy from B2
A6: =COUNTIF(B$8:E$12,"*"&$A$1)
B6: =COUNTIF(B$8:B$12,"*"&$A$1)
C6:E6: Copy from B6

如要增加車位或欄位，可在例子數據範圍內加行或列，公式將可自行調整參考數據範圍，只須將公式抄至新增的相應單元格內即可。最後版面樣子如下：

123BB123/CP01AC123/CP02AT123/CP03GM123/CP04
輸入車牌BC123/CP02GF123/CP044123/CP05
123/CP05MM123/CP05

車牌/車位1車牌/車位2車牌/車位3車牌/車位4
93321
車場車位車位車牌1車位車牌2車位車牌3車位車牌4
CP01BB123AA135PQ456CA138
CP02BC123AC123AM999CN168
CP03BD234HK168AT123
CP04ILUGF123GM123
CP05123MM1234123

2014-10-15 14:43:23 補充：
由於回答字數已達上限無法補充，所以改在此意見欄續答：
(三)當你換轉喺A2打車牌，用VLOOKUP就搵唔到車位，係受到VLOOKUP使用上的限制---只能以最左的一行作為關鍵資料，而輸出資料的行必須在右方(行數是正數)，要做到輸出在關鍵資料左方的行，可改用MATCH功能。
(四)如用MATCH功能，可以將*號放到公式裡面，輸入時就不用按*號，打444已經可以搵到R001車位。例：MATCH("*"&$A$1,B$8:B$12,0)。
(五) 我係靠自學EXCEL，經互聯網搜尋慢慢累積經驗，故未能推薦課程。

2014-10-18 18:38:15 補充：
Try: =TRIM(MATCH("*"&$A$1,$B:$B,0)&" "&MATCH("*"&$A$1,$C:$C,0)&" "&MATCH("*"&$A$1,$D:$D,0)&" "&MATCH("*"&$A$1,$E:$E,0))

謝謝!我見條式(=MATCH("*"&$A$1,B$8:B$12,0)),我將後面(B$8:B$12)改做$B:$E後,就冇反應,請賜教!