EXCEL 函數應用問題.........

💻 軟件台軟體

[匿名]

2011-03-08 8:16 am

IJAAACAJAKALAM1機台班別類別產量機台班別D1+D2D3+E22F01AD13F01A573F01BD11B154F01AD22F02A　　5F01AD35B　　6F01BE24C　　7F01AE22D　　8F01BD31　　　　9F01BE12　　　　
資料如上表左所示，計算結果如上表右所示。請問我要怎樣利用 EXCEL 函數編寫計算公式，愈簡單明瞭越好，請各位高手協助腦力激盪。感謝不盡

更新1:

首先感謝 Daniel 您的答覆，可能是我敘述不夠完整，我補充說明如下：問1. 在F01機台A班生產的D1=3,D2=2,所以AL欄(D1+D2)有5個。 2. 在F01機台A班生產的D3=5,E2=2,所以AM欄(D3+E2)有7個。 3. 在F01機台B班生產的D1=1,D2=無,所以AL欄(D1+D2)有1個。 4. 在F01機台B班生產的D3=1,E2=4,所以AM欄(D3+E2)有5個此計算表在(sheet2) 以上計算公式在D欄&E欄分別該怎麼寫入。請您再次協助感謝

更新2:

以上計算公式在AL欄&AM欄分別該怎麼寫入。請您再次協助感謝

更新3:

Daniel 大您好：我結合您的公式是可用的，在這我想再問一點，如果我的AA欄裡的類別會有D1、D2、D3、D4或E1、E2、E3、E4；如果我的AL1或AM1欄要改成(D2+D3+D4)或(E2+E3+E4)的話要怎麼修改，我自己有試過修改發現並不正確，請您再次指點迷津。謝謝

更新4:

Daniel 大您好：我試著用複製您所寫的公式在儲存格貼上，並無法達到所需結果，是否我哪邊操作錯誤，能否請您用結合附件的方式，我去下載。因為我如果在儲存格上直接修改公式，並不會成為計算式，而是變成一個字串而已。謝謝您 PS.是否跟我使用 OFFICE 2003 有關

更新5:

Daniel 大我想我已經知道修改的方法了，謝謝您了，我先試試看，如有不懂不明瞭實在請您指點迷津。

回答 (3)

Daniel

2011-03-08 5:58 pm

✔ 最佳答案

AL2公式:
=SUM(($I$2:$I$9=INDEX($AJ:$AJ,MAX(IF(ISTEXT($AJ$2:$AJ2),ROW($AJ$2:$AJ2)))))*($J$2:$J$9=$AK2)*(($AA$2:$AA$9=LEFT(AL$1,2))+($AA$2:$AA$9=RIGHT(AL$1,2)))*$AC$2:$AC$9)

陣列公式, 輸入完後同時按 [Ctrl]+[Shift]+[Enter]

向右向下複製公式

2011-03-08 10:22:17 補充：
若分別設定下列名稱:
[機台] 參照到 [ =OFFSET($I$2,,,COUNTA(Sheet1!$I:$I)-1,) ]
[班別] 參照到 [ =OFFSET($J$2,,,COUNTA(Sheet1!$I:$I)-1,) ]
[類別] 參照到 [ =OFFSET($AA$2,,,COUNTA(Sheet1!$I:$I)-1,) ]
[產量] 參照到 [ =OFFSET($AC$2,,,COUNTA(Sheet1!$I:$I)-1,) ]

2011-03-08 10:22:26 補充：
則AL公式:
=SUM((機台=INDEX($AJ:$AJ,MAX(IF(ISTEXT($AJ$2:$AJ2),ROW($AJ$2:$AJ2)))))*(班別=$AK2)*((類別=LEFT(AL$1,2))+(類別=RIGHT(AL$1,2)))*產量)

此時可自動增加資料數

2011-03-10 01:00:29 補充：
參考a大的公式, 結合如附件:
http://www.funp.net/557983

2011-03-12 00:01:34 補充：
AL1或AM1欄要改成(D2+D3+D4)或(E2+E3+E4),
則AL2公式:
=SUM((機台=INDEX($AJ:$AJ,MATCH("龘",$AJ$1:$AJ2)))*(班別=$AK2)*(類別=MID(AL$1,{1,4,7,10},2))*產量)

向右向下複製

👍 0 👎 0

[匿名]

2011-03-08 6:30 pm

AL2=SUMPRODUCT(($I$2:$I$1000=INDEX($AJ:$AJ,MATCH("龘",$AJ$1:$AJ2)))*($J$2:$J$1000=$AK2)*($AA$2:$AA$1000=MID(AL$1,{1,4},2))*$AC$2:$AC$1000)
向右向下複製公式

👍 0 👎 0

[匿名]

2011-03-08 3:54 pm

左表欄位為A1~D17，左表欄位為F1~I17

H2=SUMPRODUCT(($A$2:$A$9=$F$2)*($B$2:$B$9=$G2)*(($C$2:$C$9=LEFT(H$1,2))+($C$2:$C$9=RIGHT(H$1,2)))*$D$2:$D$9)
右拉下拉到I3

H4=SUMPRODUCT(($A$2:$A$17=$F$4)*($B$2:$B$17=$G4)*(($C$2:$C$17=LEFT(H$1,2))+($C$2:$C$17=RIGHT(H$1,2)))*$D$2:$D$17)
右拉下拉到I7

2011-03-08 08:29:41 補充：
機台若很多，建議F欄不要用合併儲存格，這樣就可以一條供式拉到底，否則一個機台就要寫一條公式

👍 0 👎 0

收錄日期: 2021-05-03 04:38:56
原文連結 [永久失效]:
https://hk.answers.yahoo.com/question/index?qid=20110308000016KK00143

檢視 Wayback Machine 備份