EXCEL問題

公式:
=IF((D2>=301)*(D2<=2100),LOOKUP(D2,{301,901,1501},{"a","b","c"}),"超出範圍")


2009-08-13 23:18:53 補充：
=IF((D2>=301)*(D2<=2359),LOOKUP(D2,{301,901,1501,2101},{"a","b","c","d"}),"超出範圍")

除上述以外, LOOKUP部份亦可寫為:

CHOOSE(ROUNDUP((D2-300)/600,),"a","b","c","d")

或參考 rc 大大的方式再改一下:

CHAR(96+ROUNDUP((D2-300)/600,))

2009-08-13 23:24:05 補充：
如果大於2400要顯示什麼?

各位前輩都很厲害，我也來貢獻一下我用的笨方法，
就是直接把題目的幾個公式寫在一個公式裡。
答案是：

=IF(OR(D2>=301, D2<=900), "a",
IF(OR(D2>=901, D2<=1500), "b",
IF(OR(D2>=1501, D2<=2100), "c",
IF(OR(AND(D2>=2101, D2<=2359), (D2<=300)), "d", "以上皆非"))))

這樣符合題目的要求，而且一目瞭然，
但是有個問題，
無論 D2 的值是多少，顯示出來的永遠是 "a"！

因為題目出錯了，
OR(D2>=301, D2<=900) 這個公式有筆誤，它永遠成立！
若 D2>=301 當然顯示 "a"
但若 D2<301 則必定符合 D2<=900 ，也是顯示 "a" 。
所以應該用 AND() 比較合乎邏輯。

因此，揣摩原意，我把公式改為
=IF(AND(D2>=301, D2<=900), "a",
IF(AND(D2>=901, D2<=1500), "b",
IF(AND(D2>=1501, D2<=2100), "c",
IF(OR(AND(D2>=2101, D2<=2359), (D2<=300)), "d", "以上皆非，D2 > 2359喔！"))))
應該才是版主要的邏輯。

補充說明：
IF() 函數有３個參數，
它的語法是 IF(測試邏輯, 邏輯成立時的值, 邏輯不成立時的值)，
如果省略第３個參數，當條件不成立時，會顯示 "FALSE" 或 0。

版主出的題目通通沒寫第３個參數，
如果把第３個參數也寫進來，直覺地寫法就是寫成我講的這個樣子。

嗯~~偷A一下Daniel 大大的公式~~
在下會的函數實在有限呀>Q<+
還請Daniel大大見諒~~>"<+

不過Daniel大大忽略了一點...
2009-08-13 21:38:32 補充
IF(OR(AND(D2>=2101,D2<=2359),(D2<=300)),"d")也加在同一個公式呢？
上面有用到OR,
也就表示D2所含的是小於等於300或者介於2101~2359的數值>Q<||

所以在下在前面多加了個IF,又偷偷把超出2400的數值加了"超出範圍"~~

=IF(D2<301,"D",IF(D2>=2400,"超出範圍",CHOOSE(ROUNDUP((D2-300)/600,),"a","b","c","d")))

2009-08-14 07:21:20 補充：
又有小錯誤了T.T
上面打錯...嘿嘿......正確應該是↓

也就表示"d"所含的是小於等於300或者介於2101~2359的數值>Q<||

所以正確的公式是
=IF(D2<301,"d",IF(D2>=2400,"超出範圍",CHOOSE(ROUNDUP((D2-300)/600,),"a","b","c","d")))

剛才忘了把300以下的d改成小寫>"

另一解法
=IF((A2<301)+(A2>2100),"超出範圍",CHAR(97+INT((A2-301)/600)))

如果肯定不會超出範圍，則可縮短為
=CHAR(97+INT((A2-301)/600))